home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
pc
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO021.dsk
/
FIX.PRODOS1.2.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
1KB
|
30 lines
10 REM Stop ProDOS Track 0 trashing
20 REM Patches by Stephen Thomas
30 REM MacLagan Wright & Associates
40 REM West Heidelberg, VIC Australia
100 TEXT : HOME :D$ = CHR$(4):E = 0
110 VTAB 12: PRINT "Now patching ProDOS 1.2"
120 ONERR GOTO 500
130 IF PEEK(116) <96 THEN E = 1: GOTO 500: REM Make sure there's room
140 PRINT D$;"UNLOCK PRODOS"
150 PRINT D$;"BLOAD PRODOS,A$2000,TSYS"
200 FOR ADR = 22723 TO 22732 STEP 3: REM Change 4 STAs to LDAs
210 IF PEEK(ADR) = 189 THEN E = 2: GOTO 500
220 IF PEEK(ADR) < >157 THEN E = 3: GOTO 500
230 POKE ADR,189
240 NEXT
300 ADR = 20996:V(0) = 189:V(1) = 142:V(2) = 192: REM Change NOPs to LDA $C08E,X
310 FOR I = 0 TO 2
320 IF PEEK(ADR +I) < >234 THEN E = 3: GOTO 500
330 POKE ADR +I,V(I)
340 NEXT
400 PRINT D$;"BSAVE PRODOS,A$2000,TSYS"
410 PRINT D$;"LOCK PRODOS"
420 PRINT : PRINT "Patches completed."
430 END
500 PRINT CHR$(7);"Error! No patches were made."
510 ON E GOTO 530,540,550
520 PRINT "ProDOS file not found.": END
530 PRINT "Not enough room to load ProDOS.": END
540 PRINT "File has already been patched.": END
550 PRINT "This version of ProDOS is not 1.2"